{
        time { utc "2006-06-21T12:00:00.0000" }

 	preloadtex { object "Sol/Earth" }
	preloadtex { object "Sol/Earth/Moon" }
	wait { duration 1.5 }

	timerate { rate 1 }
	labels { clear "planets|minorplanets|stars|constellations" }
	renderflags { set "stars|planets"
                      clear "galaxies|constellations|orbits|cloudmaps" }

	print { text "Welcome to Earth" row -3 }
	select { object "Sol/Earth" }
	goto { time 0.5 distance 6 upframe "equatorial" }
        gotolonglat {time 3.0  distance 6  longitude 0.0 latitude 23.45}
	synchronous {}
	wait { duration 2.0 }
	follow {}

	print { text "We're now orbiting about 40000km above the Earth." row -3 duration 5 }
	timerate { rate 1 }
	orbit { axis [ 0 -1 0 ] rate 30 duration 10 }
	print { text "This is midsummer's day in the UK." row -3 duration 5 }
	orbit { axis [ 0 -1 0 ] rate 30 duration 9.2 }
	print { text "Look for lights in the cities on the dark side of the planet." row -3}
	orbit { axis [ 0 -1 0 ] rate 30 duration 8.5 }

	print { text "Let's stop orbiting, then speed up time to see Earth rotate." row -3 duration 6 }
	timerate { rate 2000 }
	wait { duration 10.0 }
	print { text "Watch how the North pole stays in the light but Antarctica stays dark." row -3 duration 6 }
	wait { duration 13.0 }

	print { text "Now let's change the date to December 21st." row -3 duration 5 }
	wait { duration 2.0 }
        time { utc "2006-12-21T12:00:00.0000" }
	wait { duration 3.0 }
	print { text "Notice how the North pole is now always dark and the South pole is always light." row -3 duration 5 }
	wait { duration 15.0 }

	print { text "Let's slow down time again and orbit to see the pattern of light and dark." row -3 duration 5 }
	timerate { rate 1 }
	wait { duration 0.5 }
	orbit { axis [ 0 -1 0 ] rate 30 duration 20 }
	print { text "Let's follow the UK to watch a day in winter in our hemisphere." row -3 duration 5 }
        gotolonglat {time 1.0  distance 6  longitude 0.0 latitude 23.45}
	wait { duration 1.5 }

        setframe { ref "Sol/Earth"
                   target "Sol/Earth"           
                   coordsys "geographic" }
	timerate { rate 4000 }
	wait { duration 40 }
	print { text "Finally, compare this how much light we get on a day in summer." row -3 duration 5 }
        time { utc "2006-06-21T12:00:00.0000" }

	wait { duration 5 }
	print { text "More simulations at cjtonline.net." row -3 duration 5 }

}